Sakana labs

[AS3] Classe TimelineController

Parfois j'ai besoin de pouvoir contrôler la Timeline d'un MovieClip autrement que juste play, stop, gotoAnd...
Alors pour raccourcir la longueur de mon code source je me suis inspiré de TweenLite pour développer une petite classe TimelineController.

Trois méthodes statiques :

• TimelineController.to(target:MovieClip, frame:Number) : permet de se rendre à une image précise sur la timeline de la façon la plus rapide. En résumé, si vous être sur l'image 5 et que vous devez aller sur l'image 100 (la dernière de votre timeline dans ce cas), la tête de lecture va partir vers l'arrière et passer par 1 pour atteindre l'image 100
• TimelineController.reverse(target:MovieClip) : permet de lire la timeline à l'envers
• TimelineController.once(target:MovieClip) : permet de lire la timeline "une fois" et s'arrête sur la dernière frame.

Comme pour TweenLite vous pouvez ajouter un objet en paramètre. Pour l'instant je n'utilise que la propriété onComplete et onCompleteParams. Pour déclencher une méthode lorsque l'image cible est atteinte.

TimelineController.as :

package  {
import flash.display.MovieClip;
import flash.events.Event;
 
public class TimelineController {
	private var _target:MovieClip
	private var _destinationFrame:Number;
	private var _direction:String;
	private var _params:Object;
 
public function TimelineController(aTarget:MovieClip, aDestinationFrame:Number = undefined, aDirection:String = undefined, aObject:Object = null ):void {
	_target = aTarget;
	_destinationFrame = aDestinationFrame;
	_params = new Object();
	if (aObject != null) _params = aObject;
	if (aDirection) {
		_direction = aDirection;
	}else {
		_direction = findQuickPath();
	}
	_target.addEventListener(Event.ENTER_FRAME, handleEnterFrame);
}
 
public static function to(aTarget:MovieClip, aDestinationFrame:Number, aObject:Object = null):TimelineController {
	return new TimelineController(aTarget, aDestinationFrame, undefined, aObject);
}
 
public static function once(aTarget:MovieClip, aObject:Object = null):TimelineController {
	return new TimelineController(aTarget, aTarget.totalFrames, "forward", aObject);
}
 
public static function reverse(aTarget:MovieClip, aObject:Object = null):TimelineController {
	return new TimelineController(aTarget, 1, "backward", aObject);
}
 
private function findQuickPath():String {
	var distance:Number =  _destinationFrame - _target.currentFrame;
	if (Math.abs(distance) > _target.totalFrames / 2) distance = -(distance);
	if (distance > 0) {
		return "forward";
	}else {
		return "backward";
	}
}
 
private function handleEnterFrame(e:Event):void {
	switch(_direction) {
case "forward":if (_target.currentFrame +1 <= _target.totalFrames) {
				_target.nextFrame();
			}else {
				_target.gotoAndStop(1);
			}
			break;
case "backward":if (_target.currentFrame -1 > 0) {
				_target.prevFrame();
			}else {
				_target.gotoAndStop(_target.totalFrames);
			}
			break;
			}
if (_target.currentFrame == _destinationFrame) {
	_target.removeEventListener(Event.ENTER_FRAME, handleEnterFrame);
if (_params.onComplete != null) _params.onComplete.apply(null, _params.onCompleteParams);
	}
	}
}
}

Pour le moment je n'ai pas besoin de plus que ces trois méthodes mais si vous avez des idées...